Function: org-ascii-keyword

org-ascii-keyword is a byte-compiled function defined in ox-ascii.el.gz.

Signature

(org-ascii-keyword KEYWORD CONTENTS INFO)

Documentation

Transcode a KEYWORD element from Org to ASCII.

CONTENTS is nil. INFO is a plist holding contextual information.

Source Code

;; Defined in /usr/src/emacs/lisp/org/ox-ascii.el.gz
;;;; Keyword

(defun org-ascii-keyword (keyword _contents info)
  "Transcode a KEYWORD element from Org to ASCII.
CONTENTS is nil.  INFO is a plist holding contextual
information."
  (let ((key (org-element-property :key keyword))
	(value (org-element-property :value keyword)))
    (cond
     ((string= key "ASCII") (org-ascii--justify-element value keyword info))
     ((string= key "TOC")
      (org-ascii--justify-element
       (let ((case-fold-search t))
	 (cond
	  ((string-match-p "\\<headlines\\>" value)
	   (let ((depth (and (string-match "\\<[0-9]+\\>" value)
			     (string-to-number (match-string 0 value))))
		 (scope
		  (cond
		   ((string-match ":target +\\(\".+?\"\\|\\S-+\\)" value) ;link
		    (org-export-resolve-link
		     (org-strip-quotes (match-string 1 value)) info))
		   ((string-match-p "\\<local\\>" value) keyword)))) ;local
	     (org-ascii--build-toc info depth keyword scope)))
	  ((string-match-p "\\<tables\\>" value)
	   (org-ascii--list-tables keyword info))
	  ((string-match-p "\\<listings\\>" value)
	   (org-ascii--list-listings keyword info))))
       keyword info)))))