Function: org-babel-C-var-to-C

org-babel-C-var-to-C is a byte-compiled function defined in ob-C.el.gz.

Signature

(org-babel-C-var-to-C PAIR)

Documentation

Convert an elisp val into a string of C code specifying a var of the same value.

Source Code

;; Defined in /usr/src/emacs/lisp/org/ob-C.el.gz
(defun org-babel-C-var-to-C (pair)
  "Convert an elisp val into a string of C code specifying a var of the same value."
  ;; TODO list support
  (let ((var (car pair))
	(val (cdr pair)))
    (when (symbolp val)
      (setq val (symbol-name val))
      (when (= (length val) 1)
	(setq val (string-to-char val))))
    (let* ((type-data (org-babel-C-val-to-C-type val))
	   (type (car type-data))
	   (formatted (org-babel-C-format-val type-data val))
	   (suffix (car formatted))
	   (data (cdr formatted)))
      (pcase org-babel-c-variant
        ((or `c `cpp)
         (format "%s %s%s = %s;"
                 type
                 var
                 suffix
                 data))
        (`d
         (format "%s%s %s = %s;"
                 type
                 suffix
                 var
                 data))))))