Function: org-babel-execute:awk

org-babel-execute:awk is a byte-compiled function defined in ob-awk.el.gz.

Signature

(org-babel-execute:awk BODY PARAMS)

Documentation

Execute a block of Awk code with org-babel.

This function is called by org-babel-execute-src-block.

Source Code

;; Defined in /usr/src/emacs/lisp/org/ob-awk.el.gz
(defun org-babel-execute:awk (body params)
  "Execute a block of Awk code with org-babel.
This function is called by `org-babel-execute-src-block'."
  (message "Executing Awk source code block")
  (let* ((result-params (cdr (assq :result-params params)))
         (cmd-line (cdr (assq :cmd-line params)))
         (in-file (cdr (assq :in-file params)))
	 (full-body (org-babel-expand-body:awk body params))
	 (code-file (let ((file (org-babel-temp-file "awk-")))
                      (with-temp-file file (insert full-body)) file))
	 (stdin (let ((stdin (cdr (assq :stdin params))))
		  (when stdin
		    (let ((tmp (org-babel-temp-file "awk-stdin-"))
			  (res (org-babel-ref-resolve stdin)))
		      (with-temp-file tmp
			(insert (org-babel-awk-var-to-awk res)))
		      tmp))))
         (cmd (mapconcat #'identity
			 (append
			  (list org-babel-awk-command
				"-f" code-file cmd-line)
			  (mapcar (lambda (pair)
				    (format "-v %s='%s'"
					    (car pair)
					    (org-babel-awk-var-to-awk
					     (cdr pair))))
				  (org-babel--get-vars params))
			  (list in-file))
			 " ")))
    (org-babel-reassemble-table
     (let ((results
            (cond
             (stdin (with-temp-buffer
                      (call-process-shell-command cmd stdin (current-buffer))
                      (buffer-string)))
             (t (org-babel-eval cmd "")))))
       (when results
         (org-babel-result-cond result-params
	   results
	   (let ((tmp (org-babel-temp-file "awk-results-")))
	     (with-temp-file tmp (insert results))
	     (org-babel-import-elisp-from-file tmp)))))
     (org-babel-pick-name
      (cdr (assq :colname-names params)) (cdr (assq :colnames params)))
     (org-babel-pick-name
      (cdr (assq :rowname-names params)) (cdr (assq :rownames params))))))