Function: org-babel-remove-temporary-directory

org-babel-remove-temporary-directory is a byte-compiled function defined in ob-core.el.gz.

Signature

(org-babel-remove-temporary-directory)

Documentation

Remove org-babel-temporary-directory on Emacs shutdown.

Source Code

;; Defined in /usr/src/emacs/lisp/org/ob-core.el.gz
(defun org-babel-remove-temporary-directory ()
  "Remove `org-babel-temporary-directory' on Emacs shutdown."
  (when (and org-babel-temporary-directory
	     (file-exists-p org-babel-temporary-directory))
    ;; taken from `delete-directory' in files.el
    (condition-case nil
	(progn
	  (mapc (lambda (file)
		  ;; This test is equivalent to
		  ;; (and (file-directory-p fn) (not (file-symlink-p fn)))
		  ;; but more efficient
		  (if (eq t (car (file-attributes file)))
		      (delete-directory file)
		    (delete-file file)))
		(directory-files org-babel-temporary-directory 'full
				 directory-files-no-dot-files-regexp))
	  (delete-directory org-babel-temporary-directory))
      (error
       (message "Failed to remove temporary Org-babel directory %s"
		(or org-babel-temporary-directory
		    "[directory not defined]"))))))