Function: org-check-dates-range

org-check-dates-range is an interactive and byte-compiled function defined in org.el.gz.

Signature

(org-check-dates-range START-DATE END-DATE)

Documentation

Check for deadlines/scheduled entries between START-DATE and END-DATE.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/org/org.el.gz
(defun org-check-dates-range (start-date end-date)
  "Check for deadlines/scheduled entries between START-DATE and END-DATE."
  (interactive (list (org-read-date nil nil nil "Range starts")
		     (org-read-date nil nil nil "Range end")))
  (let ((case-fold-search nil)
	(regexp (org-re-timestamp org-ts-type))
	(callback
	 (let ((type org-ts-type))
	   (lambda ()
	     (let ((match (match-string 1)))
	       (and
		(if (memq type '(active inactive all))
		    (eq (org-element-type (save-excursion
					    (backward-char)
					    (org-element-context)))
			'timestamp)
		  (org-at-planning-p))
		(not (time-less-p
		      (org-time-string-to-time match)
		      (org-time-string-to-time start-date)))
		(time-less-p
		 (org-time-string-to-time match)
		 (org-time-string-to-time end-date))))))))
    (message "%d entries between %s and %s"
	     (org-occur regexp nil callback) start-date end-date)))