Function: org-cite--get-note-rule

org-cite--get-note-rule is a byte-compiled function defined in oc.el.gz.

Signature

(org-cite--get-note-rule INFO)

Documentation

Return punctuation rule according to language used for export.

INFO is the export state, as a property list.

Rule is found according to the language used for export and org-cite-note-rules, which see.

If there is no rule matching current language, the rule defaults to (adaptive outside after).

Source Code

;; Defined in /usr/src/emacs/lisp/org/oc.el.gz
(defun org-cite--get-note-rule (info)
  "Return punctuation rule according to language used for export.

INFO is the export state, as a property list.

Rule is found according to the language used for export and
`org-cite-note-rules', which see.

If there is no rule matching current language, the rule defaults
to (adaptive outside after)."
  (let* ((language-tags
          ;; Normalize language as a language-region tag, as described
          ;; in RFC 4646.
          (pcase (split-string (plist-get info :language) "[-_]")
            (`(,language)
             (list language
                   (or (cdr (assoc language org-cite--default-region-alist))
                       language)))
            (`(,language ,region)
             (list language region))
            (other
             (error "Invalid language identifier: %S" other))))
         (language-region (mapconcat #'downcase language-tags "-"))
         (language (car language-tags)))
    (or (cdr (assoc language-region org-cite-note-rules))
        (cdr (assoc language org-cite-note-rules))
        '(adaptive outside after))))