Function: org-element-radio-target-parser

org-element-radio-target-parser is a byte-compiled function defined in org-element.el.gz.

Signature

(org-element-radio-target-parser)

Documentation

Parse radio target at point, if any.

When at a radio target, return a list whose car is radio-target and cdr a plist with :begin, :end, :contents-begin,
:contents-end, :value and :post-blank as keywords.
Otherwise, return nil.

Assume point is at the radio target.

Source Code

;; Defined in /usr/src/emacs/lisp/org/org-element.el.gz
;;;; Radio-target

(defun org-element-radio-target-parser ()
  "Parse radio target at point, if any.

When at a radio target, return a list whose car is `radio-target'
and cdr a plist with `:begin', `:end', `:contents-begin',
`:contents-end', `:value' and `:post-blank' as keywords.
Otherwise, return nil.

Assume point is at the radio target."
  (save-excursion
    (when (looking-at org-radio-target-regexp)
      (let ((begin (point))
	    (contents-begin (match-beginning 1))
	    (contents-end (match-end 1))
	    (value (match-string-no-properties 1))
	    (post-blank (progn (goto-char (match-end 0))
			       (skip-chars-forward " \t")))
	    (end (point)))
	(list 'radio-target
	      (list :begin begin
		    :end end
		    :contents-begin contents-begin
		    :contents-end contents-end
		    :post-blank post-blank
		    :value value))))))