Function: org-num--skip-value

org-num--skip-value is a byte-compiled function defined in org-num.el.gz.

Signature

(org-num--skip-value)

Documentation

Return skip value for headline at point.

Value is t when headline should not be numbered, and nil otherwise.

Source Code

;; Defined in /usr/src/emacs/lisp/org/org-num.el.gz
(defun org-num--skip-value ()
  "Return skip value for headline at point.
Value is t when headline should not be numbered, and nil
otherwise."
  (org-match-line org-complex-heading-regexp)
  (let ((title (match-string 4))
        (tags (and org-num-skip-tags
                   (match-end 5)
                   (org-split-string (match-string 5) ":"))))
    (or (and org-num-skip-footnotes
             org-footnote-section
             (equal title org-footnote-section))
        (and org-num-skip-commented
	     title
             (let ((case-fold-search nil))
               (string-match org-num--comment-re title))
             t)
        (and org-num-skip-tags
             (cl-some (lambda (tag) (member tag org-num-skip-tags))
                      tags)
             t)
        (and org-num-skip-unnumbered
             (org-entry-get (point) "UNNUMBERED")
             t))))