Function: org-org-section

org-org-section is a byte-compiled function defined in ox-org.el.gz.

Signature

(org-org-section SECTION CONTENTS INFO)

Documentation

Transcode SECTION element back into Org syntax.

CONTENTS is the contents of the section. INFO is a plist used as a communication channel.

Source Code

;; Defined in /usr/src/emacs/lisp/org/ox-org.el.gz
(defun org-org-section (section contents info)
  "Transcode SECTION element back into Org syntax.
CONTENTS is the contents of the section.  INFO is a plist used as
a communication channel."
  (concat
   (org-element-normalize-string contents)
   ;; Insert footnote definitions appearing for the first time in this
   ;; section, or in the relative headline title.  Indeed, some of
   ;; them may not be available to narrowing so we make sure all of
   ;; them are included in the result.
   (let ((footnotes
	  (org-element-map
	      (list (org-export-get-parent-headline section) section)
	      'footnote-reference
	    (lambda (fn)
	      (and (eq (org-element-property :type fn) 'standard)
		   (org-export-footnote-first-reference-p fn info)
		   (org-element-normalize-string
		    (format "[fn:%s] %s"
			    (org-element-property :label fn)
			    (org-export-data
			     (org-export-get-footnote-definition fn info)
			     info)))))
	    info nil 'headline t)))
     (and footnotes (concat "\n" (mapconcat #'identity footnotes "\n"))))))