Function: pascal-indent-paramlist

pascal-indent-paramlist is a byte-compiled function defined in pascal.el.gz.

Signature

(pascal-indent-paramlist &optional ARG)

Documentation

Indent current line in parameterlist.

If optional ARG is non-nil, just return the indent of the current line in parameterlist.

Source Code

;; Defined in /usr/src/emacs/lisp/progmodes/pascal.el.gz
(defun pascal-indent-paramlist (&optional arg)
  "Indent current line in parameterlist.
If optional ARG is non-nil, just return the
indent of the current line in parameterlist."
  (save-excursion
    (let* ((oldpos (point))
	   (stpos (progn (goto-char (scan-lists (point) -1 1)) (point)))
	   (stcol (1+ (current-column)))
	   (edpos (progn (pascal-declaration-end)
                         (search-backward ")" (line-beginning-position) t)
			 (point)))
	   (usevar (re-search-backward "\\<var\\>" stpos t)))
      (if arg (progn
		;; If arg, just return indent
		(goto-char oldpos)
		(beginning-of-line)
		(if (or (not usevar) (looking-at "[ \t]*var\\>"))
		    stcol (+ 4 stcol)))
	(goto-char stpos)
	(forward-char 1)
	(delete-horizontal-space)
	(if (and usevar (not (looking-at "var\\>")))
	    (indent-to (+ 4 stcol)))
	(pascal-indent-declaration nil stpos edpos)))))