Function: pcomplete/rclone

pcomplete/rclone is an autoloaded and byte-compiled function defined in pcmpl-x.el.gz.

Signature

(pcomplete/rclone)

Documentation

Completion for the rclone command.

Source Code

;; Defined in /usr/src/emacs/lisp/pcmpl-x.el.gz
;;; Network tools

;;;###autoload
(defun pcomplete/rclone ()
  "Completion for the `rclone' command."
  (let ((subcmds (pcomplete-from-help "rclone help"
                                      :margin "^  "
                                      :argument "[a-z]+"
                                      :narrow-start "\n\n")))
    (while (not (member (pcomplete-arg 1) subcmds))
      (pcomplete-here (completion-table-merge
                       subcmds
                       (pcomplete-from-help "rclone help flags"))))
    (let ((subcmd (pcomplete-arg 1)))
      (while (if (pcomplete-match "\\`-" 0)
                 (pcomplete-here (pcomplete-from-help
                                  `("rclone" ,subcmd "--help")))
               (pcomplete-here (pcomplete-entries)))))))