Function: preview-pdf2dsc-sentinel

preview-pdf2dsc-sentinel is a byte-compiled function defined in preview.el.

Signature

(preview-pdf2dsc-sentinel PROCESS COMMAND &optional GSSTART)

Documentation

Sentinel function for indirect rendering PDF process.

The usual PROCESS and COMMAND arguments for TeX-sentinel-function apply. Starts gs if GSSTART is set.

Source Code

;; Defined in ~/.emacs.d/elpa/auctex-14.1.2/preview.el
(defun preview-pdf2dsc-sentinel (process _command &optional gsstart)
  "Sentinel function for indirect rendering PDF process.
The usual PROCESS and COMMAND arguments for
`TeX-sentinel-function' apply.  Starts gs if GSSTART is set."
  (condition-case err
      (let ((status (process-status process)))
        (cond ((eq status 'exit)
               (delete-process process)
               (setq TeX-sentinel-function nil)
               ;; Add DELAYBIND option for adjustment of foreground
               ;; color to work.
               (if (and (eq preview-pdf-color-adjust-method t)
                        (aref preview-colors 1))
                   (setq preview-gs-command-line (append
                                                  preview-gs-command-line
                                                  '("-dDELAYBIND"))))
               (setq preview-gs-init-string
                     (concat preview-gs-init-string
                             (preview-pdf-color-string preview-colors)))
               (preview-prepare-fast-conversion)
               (when gsstart
                 (if preview-gs-queue
                     (preview-gs-restart)
                   (when preview-ps-file
                     (condition-case nil
                         (preview-delete-file preview-ps-file)
                       (file-error nil))))))
              ((eq status 'signal)
               (delete-process process)
               (preview-dvips-abort))))
    (error (preview-log-error err "PDF2DSC sentinel" process)))
  (preview-reraise-error process))