Function: repeat-echo-message

repeat-echo-message is a byte-compiled function defined in repeat.el.gz.

Signature

(repeat-echo-message KEYMAP)

Documentation

Display in the echo area the repeating keys defined by KEYMAP.

See repeat-echo-function to enable/disable.

Source Code

;; Defined in /usr/src/emacs/lisp/repeat.el.gz
(defun repeat-echo-message (keymap)
  "Display in the echo area the repeating keys defined by KEYMAP.
See `repeat-echo-function' to enable/disable."
  (let ((message-log-max nil))
    (if keymap
        (let ((message (repeat-echo-message-string keymap)))
          (if (current-message)
              (message "%s [%s]" (current-message) message)
            (message "%s" message)))
      (let ((message (current-message)))
        (when message
          (cond
           ((string-prefix-p "Repeat with " message)
            (message nil))
           ((string-search " [Repeat with " message)
            (message "%s" (replace-regexp-in-string
                           " \\[Repeat with .*\\'" "" message)))))))))