Function: rmail-mime-insert-tagline

rmail-mime-insert-tagline is a byte-compiled function defined in rmailmm.el.gz.

Signature

(rmail-mime-insert-tagline ENTITY &rest ITEM-LIST)

Documentation

Insert a tag line for MIME-entity ENTITY.

ITEM-LIST is a list of strings or button-elements (list) to add to the tag line.

Source Code

;; Defined in /usr/src/emacs/lisp/mail/rmailmm.el.gz
;;; Handlers

(defun rmail-mime-insert-tagline (entity &rest item-list)
  "Insert a tag line for MIME-entity ENTITY.
ITEM-LIST is a list of strings or button-elements (list) to add
to the tag line."
  ;; Precede the tagline by an empty line to make it a separate
  ;; paragraph, so that it is aligned to the left margin of the window
  ;; even if preceded by a right-to-left paragraph.
  (insert "\n[")
  (let ((tag (aref (rmail-mime-entity-tagline entity) 0)))
    (if (> (length tag) 0) (insert (substring tag 1) ":")))
  (insert (car (rmail-mime-entity-type entity)) " ")
  (insert-button (let ((new (aref (rmail-mime-entity-display entity) 1)))
		   (if (rmail-mime-display-body new) "Hide" "Show"))
		 :type 'rmail-mime-toggle
		 'help-echo "mouse-2, RET: Toggle show/hide")
  (dolist (item item-list)
    (when item
      (if (stringp item)
	  (insert item)
	(apply #'insert-button item))))
  ;; Follow the tagline by an empty line to make it a separate
  ;; paragraph, so that the paragraph direction of the following text
  ;; is determined based on that text.
  (insert "]\n\n"))