Function: ses-read-cell

ses-read-cell is an interactive and byte-compiled function defined in ses.el.gz.

Signature

(ses-read-cell ROW COL NEWVAL)

Documentation

Self-insert for initial character of cell function.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/ses.el.gz
(defun ses-read-cell (row col newval)
  "Self-insert for initial character of cell function."
  (interactive
   (let* ((initial (this-command-keys))
          (rowcol  (progn (ses-check-curcell) (ses-sym-rowcol ses--curcell)))
          (curval (ses-cell-formula (car rowcol) (cdr rowcol))))
     (barf-if-buffer-read-only)
     (list (car rowcol)
	   (cdr rowcol)
           (if (equal initial "\"")
               (progn
                 (if (not (stringp curval)) (setq curval nil))
                 (read-string (format-prompt "String Cell %s"
                                             curval ses--curcell)
                              nil 'ses-read-string-history curval))
             (read-from-minibuffer
              (format "Cell %s: " ses--curcell)
              (cons (if (equal initial "(") "()" initial) 2)
              ses-mode-edit-map
              t                         ; Convert to Lisp object.
              'ses-read-cell-history
              (prin1-to-string (if (eq (car-safe curval) 'ses-safe-formula)
                                   (cadr curval)
                                 curval)))))))
  (when (ses-edit-cell row col newval)
    (ses-command-hook) ; Update cell widths before movement.
    (dolist (x ses-after-entry-functions)
      (funcall x 1))))