Function: smart-man-c-routine-ref

smart-man-c-routine-ref is a byte-compiled function defined in hui-mouse.el.

Signature

(smart-man-c-routine-ref)

Documentation

Return form to jump to the definition of the named C function at point.

Valid sections within the man page are: ROUTINES, MACROS or FUNCTIONS. Uses (smart-tags-file-list) function to determine the tags file from which to locate the definition.

Source Code

;; Defined in ~/.emacs.d/elpa/hyperbole-20260414.325/hui-mouse.el
(defun smart-man-c-routine-ref ()
  "Return form to jump to the definition of the named C function at point.
Valid sections within the man page are: ROUTINES, MACROS or FUNCTIONS.
Uses (smart-tags-file-list) function to determine the tags file from which to
locate the definition."
  (let ((ref)
	(opoint (point))
	(case-fold-search))
    (save-excursion
      (and (re-search-backward "^[.A-Z]" nil t)
	   (looking-at "^\\(FUNCTIONS\\|ROUTINES\\|MACROS\\)[ \t\n\r]")
	   (progn (goto-char opoint)
		  (skip-chars-backward "_~<>:a-zA-Z0-9(")
		  (if (or (looking-at "\\([_~<>:a-zA-Z0-9]+\\)[ \t\n\r]*(")
			  (looking-at "\\([_~<:A-Z][_<>:A-Z0-9]+\\)"))
		      (setq ref (buffer-substring
				 (match-beginning 1) (match-end 1)))))))
    (if ref
	(list 'smart-tags-display ref nil
	      (smart-tags-file-list (or (and (boundp 'Man-header-file-path)
					     Man-header-file-path)
					(and (boundp 'man-path) man-path)))))))