Function: srecode-semantic-handle-:java

srecode-semantic-handle-:java is an autoloaded and byte-compiled function defined in java.el.gz.

Signature

(srecode-semantic-handle-:java DICT)

Documentation

Add macros into the dictionary DICT based on the current java file.

Adds the following: FILENAME_AS_PACKAGE - file/dir converted into a java package name. FILENAME_AS_CLASS - file converted to a Java class name.

Source Code

;; Defined in /usr/src/emacs/lisp/cedet/srecode/java.el.gz
;;;###autoload
(defun srecode-semantic-handle-:java (dict)
  "Add macros into the dictionary DICT based on the current java file.
Adds the following:
FILENAME_AS_PACKAGE - file/dir converted into a java package name.
FILENAME_AS_CLASS - file converted to a Java class name."
  ;; Symbols needed by empty files.
  (let* ((fsym (file-name-nondirectory (buffer-file-name)))
	 (fnox (file-name-sans-extension fsym))
	 (dir (file-name-directory (buffer-file-name)))
	 (fpak fsym)
	 (proj (ede-current-project))
	 (pths (ede-source-paths proj 'java-mode))
	 )
    (while (string-match "\\.\\| " fpak)
      (setq fpak (replace-match "_" t t fpak)))
    ;; We can extract package from:
    ;; 1) a java EDE project source paths,
    (cond ((and proj pths)
           (let* ((pth) (res))
             (while (and (not res)
                         (setq pth (expand-file-name (car pths))))
               (when (string-match pth dir)
                 (setq res (substring dir (match-end 0))))
               (setq pths (cdr pths)))
             (setq dir res)))
          ;; 2) a simple heuristic
          ((string-match "src/" dir)
           (setq dir (substring dir (match-end 0))))
          ;; 3) outer directory as a fallback
          (t (setq dir (file-name-nondirectory (directory-file-name dir)))))
    (setq dir (directory-file-name dir))
    (while (string-match "/" dir)
      (setq dir (replace-match "." t t dir)))
    (srecode-dictionary-set-value dict "FILENAME_AS_PACKAGE" dir)
    (srecode-dictionary-set-value dict "FILENAME_AS_CLASS" fnox)
    )
  ;; Symbols needed for most other files with stuff in them.
  (let ((pkg (semantic-find-tags-by-class 'package (current-buffer))))
    (when pkg
      (srecode-dictionary-set-value dict "CURRENT_PACKAGE" (semantic-tag-name (car pkg)))
      ))
  )