Function: texinfo-multi-files-insert-main-menu

texinfo-multi-files-insert-main-menu is a byte-compiled function defined in texnfo-upd.el.gz.

Signature

(texinfo-multi-files-insert-main-menu MENU-LIST)

Documentation

Insert formatted main menu at point.

Indents the first line of the description, if any, to the value of texinfo-column-for-description.

Source Code

;; Defined in /usr/src/emacs/lisp/textmodes/texnfo-upd.el.gz
(defun texinfo-multi-files-insert-main-menu (menu-list)
  "Insert formatted main menu at point.
Indents the first line of the description, if any, to the value of
`texinfo-column-for-description'."

  (insert "@menu\n")
  (dolist (entry menu-list)
    ;; Every menu entry starts with a star and a space.
    (insert "* ")

    ;; Insert the node name (and menu entry name, if present).
    (let ((node-part (car entry)))
      (if (stringp node-part)
	  ;; "Double colon" entry line; menu entry and node name are the same,
	  (insert (format "%s::" node-part))
	;; "Single colon" entry line; menu entry and node name are different.
	(insert (format "%s: %s." (car node-part) (cdr node-part)))))

    ;; Insert the description, if present.
    (when (cdr entry)
      ;; Move to right place.
      (indent-to texinfo-column-for-description 2)
      ;; Insert description.
      (insert (format "%s" (cdr entry))))

    (insert "\n")) ; end this menu entry
  (insert "@end menu"))