Function: tramp-archive-autoload-file-name-regexp

tramp-archive-autoload-file-name-regexp is a macro defined in tramp-archive.el.gz.

Signature

(tramp-archive-autoload-file-name-regexp)

Documentation

Regular expression matching archive file names.

Source Code

;; Defined in /usr/src/emacs/lisp/net/tramp-archive.el.gz
;; The definition of `tramp-archive-file-name-regexp' contains calls
;; to `regexp-opt', which cannot be autoloaded while loading
;; loaddefs.el.  So we use a macro, which is evaluated only when needed.
;; Emacs 26 and earlier cannot use the autoload form
;; `tramp-compat-rx'.  So we refrain from using `rx'.
;;;###autoload
(progn (defmacro tramp-archive-autoload-file-name-regexp ()
  "Regular expression matching archive file names."
  (if (<= emacs-major-version 26)
  '(concat
    "\\`" "\\(" ".+" "\\."
      ;; Default suffixes ...
      (regexp-opt tramp-archive-suffixes)
      ;; ... with compression.
      "\\(?:" "\\." (regexp-opt tramp-archive-compression-suffixes) "\\)*"
    "\\)" ;; \1
    "\\(" "/" ".*" "\\)" "\\'") ;; \2
  `(rx
    bos
    ;; This group is used in `tramp-archive-file-name-archive'.
    (group
     (+ nonl)
     ;; Default suffixes ...
     "." (| ,@tramp-archive-suffixes)
     ;; ... with compression.
     (? "." (| ,@tramp-archive-compression-suffixes)))
    ;; This group is used in `tramp-archive-file-name-localname'.
    (group "/" (* nonl))
    eos))))