Function: tramp-handle-file-newer-than-file-p

tramp-handle-file-newer-than-file-p is a byte-compiled function defined in tramp.el.gz.

Signature

(tramp-handle-file-newer-than-file-p FILE1 FILE2)

Documentation

Like file-newer-than-file-p for Tramp files.

Source Code

;; Defined in /usr/src/emacs/lisp/net/tramp.el.gz
(defun tramp-handle-file-newer-than-file-p (file1 file2)
  "Like `file-newer-than-file-p' for Tramp files."
  (cond
   ((not (file-exists-p file1)) nil)
   ((not (file-exists-p file2)) t)
   ;; Tramp reads and writes timestamps on second level.  So we round
   ;; the timestamps to seconds without fractions.
   ;; `time-convert' has been introduced with Emacs 27.1.
   ((fboundp 'time-convert)
    (time-less-p
     (tramp-compat-funcall
      'time-convert
      (file-attribute-modification-time (file-attributes file2)) 'integer)
     (tramp-compat-funcall
      'time-convert
      (file-attribute-modification-time (file-attributes file1)) 'integer)))
   (t (time-less-p
       (file-attribute-modification-time (file-attributes file2))
       (file-attribute-modification-time (file-attributes file1))))))