Function: vhdl-align-inline-comment-region

vhdl-align-inline-comment-region is an interactive and byte-compiled function defined in vhdl-mode.el.gz.

Signature

(vhdl-align-inline-comment-region BEG END &optional SPACING NO-MESSAGE)

Documentation

Align inline comments within a region.

Groups of code lines separated by empty lines are aligned individually, if vhdl-align-groups is non-nil.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/progmodes/vhdl-mode.el.gz
(defun vhdl-align-inline-comment-region (beg end &optional spacing no-message)
  "Align inline comments within a region.
Groups of code lines separated by empty lines are aligned
individually, if `vhdl-align-groups' is non-nil."
  (interactive "r\nP")
  (save-excursion
    (let (orig pos)
      (goto-char beg)
      (beginning-of-line)
      (setq orig (point-marker))
      (setq beg (point))
      (goto-char end)
      (setq end (point-marker))
      (untabify beg end)
      (unless no-message (message "Aligning inline comments..."))
      (goto-char beg)
      (if (not vhdl-align-groups)
	  ;; align entire region
	  (vhdl-align-inline-comment-region-1 beg end spacing)
	;; align groups
	(while (and (< beg end)
		    (re-search-forward vhdl-align-group-separate end t))
	  (setq pos (point-marker))
	  (vhdl-align-inline-comment-region-1 beg pos spacing)
	  (setq beg (1+ pos))
	  (goto-char beg))
	;; align last group
	(when (< beg end)
	  (vhdl-align-inline-comment-region-1 beg end spacing)))
      (when vhdl-indent-tabs-mode
	(tabify orig end))
      (unless no-message (message "Aligning inline comments...done")))))