Function: wdired-get-previous-link

wdired-get-previous-link is a byte-compiled function defined in wdired.el.gz.

Signature

(wdired-get-previous-link &optional OLD MOVE)

Documentation

Return the next symlink target.

If OLD, return the old target. If MOVE, move point before it.

Source Code

;; Defined in /usr/src/emacs/lisp/wdired.el.gz
(defun wdired-get-previous-link (&optional old move)
  "Return the next symlink target.
If OLD, return the old target.  If MOVE, move point before it."
  (let (beg end target)
    (setq beg (previous-single-property-change (point) 'old-link nil))
    (when beg
      (when (save-excursion
              (goto-char beg)
              (and (looking-at " ")
                   (looking-back " ->" (line-beginning-position))))
        (setq beg (1+ beg)))
      (if old
          (setq target (get-text-property (1- beg) 'old-link))
        (setq end (save-excursion
                    (goto-char beg)
                    (next-single-property-change beg 'end-link nil
                                                 (line-end-position))))
        (setq target (buffer-substring-no-properties beg end)))
      (if move (goto-char (1- beg))))
    (and target (wdired-normalize-filename target t))))