Variable: evil-want-C-w-delete

evil-want-C-w-delete is a customizable variable defined in evil-vars.el.

Value

t

Documentation

Whether C-w deletes a word in Insert/Ex/Search state.

Source Code

;; Defined in ~/.emacs.d/elpa/evil-20251108.138/evil-vars.el
(defcustom evil-want-C-w-delete t
  "Whether `C-w' deletes a word in Insert/Ex/Search state."
  :type 'boolean
  :group 'evil
  :set (lambda (sym value)
         (set-default sym value)
         (when (and (boundp 'evil-insert-state-map)
                    (boundp 'evil-replace-state-map))
           (cond
            ((and (not value)
                  (eq (lookup-key evil-insert-state-map (kbd "C-w"))
                      'evil-delete-backward-word))
             (define-key evil-insert-state-map (kbd "C-w") 'evil-window-map)
             (define-key evil-replace-state-map (kbd "C-w") 'evil-window-map))
            ((and value
                  (eq (lookup-key evil-insert-state-map (kbd "C-w"))
                      'evil-window-map))
             (define-key evil-insert-state-map (kbd "C-w") 'evil-delete-backward-word)
             (define-key evil-replace-state-map (kbd "C-w") 'evil-delete-backward-word))))
         (when (boundp 'evil-command-line-map)
           (cond
            ((and (not value)
                  (eq (lookup-key evil-command-line-map (kbd "C-w"))
                      'evil-delete-backward-word))
             (define-key evil-command-line-map (kbd "C-w") nil))
            ((and value
                  (null (lookup-key evil-command-line-map (kbd "C-w"))))
             (define-key evil-command-line-map (kbd "C-w") 'evil-delete-backward-word))))
         (when (boundp 'evil-ex-search-keymap)
           (cond
            ((and (not value)
                  (null (lookup-key evil-ex-search-keymap (kbd "C-w"))))
             (define-key evil-ex-search-keymap (kbd "C-w") 'evil-search-yank-word))
            ((and value
                  (eq (lookup-key evil-ex-search-keymap (kbd "C-w"))
                      'evil-search-yank-word))
             (define-key evil-ex-search-keymap (kbd "C-w") nil))))))