Function: TeX-source-correlate-start-server-maybe

TeX-source-correlate-start-server-maybe is a byte-compiled function defined in tex.el.

Signature

(TeX-source-correlate-start-server-maybe)

Documentation

Start Emacs server or gnuserv if a feature using it is enabled.

This is the case if TeX-source-correlate-start-server-flag is non-nil.

Source Code

;; Defined in ~/.emacs.d/elpa/auctex-14.1.2/tex.el
(defun TeX-source-correlate-start-server-maybe ()
  "Start Emacs server or gnuserv if a feature using it is enabled.
This is the case if `TeX-source-correlate-start-server-flag' is non-nil."
  (when (and TeX-source-correlate-start-server-flag
             (not (TeX-source-correlate-server-enabled-p)))
    (let* ((gnuserv-p (TeX-source-correlate-gnuserv-p))
           (start (if gnuserv-p #'gnuserv-start #'server-start)))
      (cond
       ;; Server should be started unconditionally
       ((eq TeX-source-correlate-start-server t)
        (funcall start))
       ;; Ask user if server is to be started
       ((and (eq TeX-source-correlate-start-server 'ask)
             (not TeX-source-correlate-start-server-asked)
             (prog1
                 (y-or-n-p (format "Start %s for inverse search in viewer? "
                                   (if gnuserv-p
                                       "gnuserv"
                                     "Emacs server")))
               (setq TeX-source-correlate-start-server-asked t)))
        (funcall start))))))