Function: article-decode-encoded-words

article-decode-encoded-words is a byte-compiled function defined in gnus-art.el.gz.

Signature

(article-decode-encoded-words)

Documentation

Remove encoded-word encoding from headers.

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/gnus-art.el.gz
(defun article-decode-encoded-words ()
  "Remove encoded-word encoding from headers."
  (let ((mail-parse-charset gnus-newsgroup-charset)
	(mail-parse-ignored-charsets
	 (save-excursion (condition-case nil
			     (set-buffer gnus-summary-buffer)
			   (error))
			 gnus-newsgroup-ignored-charsets))
	(inhibit-read-only t)
	end start)
    (goto-char (point-min))
    (when (search-forward "\n\n" nil 'move)
      (forward-line -1))
    (setq end (point))
    (while (not (bobp))
      (let (addresses)
        (while (progn
                 (forward-line -1)
                 (and (not (bobp))
		      (memq (char-after) '(?\t ? )))))
        (setq start (point))
        (save-restriction
          (narrow-to-region start end)
          (if (looking-at "\
\\(?:Resent-\\)?\\(?:From\\|Cc\\|To\\|Bcc\\|\\(?:In-\\)?Reply-To\\|Sender\
\\|Mail-Followup-To\\|Mail-Copies-To\\|Approved\\):")
              (progn
                (setq addresses (buffer-string))
                (funcall gnus-decode-address-function (point-min) (point-max)))
	    (funcall gnus-decode-header-function (point-min) (point-max))))
        (when addresses
          (article--check-suspicious-addresses addresses))
        (goto-char (point-max))
        (goto-char (setq end start))))))