Function: bibtex-summary

bibtex-summary is a byte-compiled function defined in bibtex.el.gz.

Signature

(bibtex-summary)

Documentation

Return summary of current BibTeX entry.

Used as default value of bibtex-summary-function.

Source Code

;; Defined in /usr/src/emacs/lisp/textmodes/bibtex.el.gz
(defun bibtex-summary ()
  "Return summary of current BibTeX entry.
Used as default value of `bibtex-summary-function'."
  ;; It would be neat to make this function customizable.  How?
  (if (looking-at bibtex-entry-maybe-empty-head)
      (let* ((bibtex-autokey-name-case-convert-function #'identity)
             (bibtex-autokey-name-length 'infty)
             (bibtex-autokey-names 1)
             (bibtex-autokey-names-stretch 0)
             (bibtex-autokey-name-separator " ")
             (bibtex-autokey-additional-names " etal")
             (names (bibtex-autokey-get-names))
             (bibtex-autokey-year-length 4)
             (year (bibtex-autokey-get-year))
             (bibtex-autokey-titlewords 5)
             (bibtex-autokey-titlewords-stretch 2)
             (bibtex-autokey-titleword-case-convert-function #'identity)
             (bibtex-autokey-titleword-length 5)
             (bibtex-autokey-titleword-separator " ")
             (title (bibtex-autokey-get-title))
             (journal (bibtex-autokey-get-field
                       "journal" bibtex-autokey-transcriptions))
             (volume (bibtex-autokey-get-field "volume"))
             (pages (bibtex-autokey-get-field "pages" '(("-.*\\'" . "")))))
        (mapconcat (lambda (arg)
                     (if (not (string= "" (cdr arg)))
                         (concat (car arg) (cdr arg))))
                   `((" " . ,names) (" " . ,year) (": " . ,title)
                     (", " . ,journal) (" " . ,volume) (":" . ,pages))
                   ""))
    (user-error "Entry not found")))