Function: c-after-conditional

c-after-conditional is a byte-compiled function defined in cc-engine.el.gz.

Signature

(c-after-conditional &optional LIM)

Source Code

;; Defined in /usr/src/emacs/lisp/progmodes/cc-engine.el.gz
(defun c-after-conditional (&optional lim)
  ;; If looking at the token after a conditional then return the
  ;; position of its start, otherwise return nil.
  ;;
  ;; This function might do hidden buffer changes.
  (save-excursion
    (and (zerop (c-backward-token-2 1 t lim))
	 (if (looking-at c-block-stmt-hangon-key)
	     (zerop (c-backward-token-2 1 t lim))
	   t)
	 (or (looking-at c-block-stmt-1-key)
	     (or
	      (and
	       (eq (char-after) ?\()
	       (zerop (c-backward-token-2 1 t lim))
	       (if (looking-at c-block-stmt-hangon-key)
		   (zerop (c-backward-token-2 1 t lim))
		 t)
	       (or (looking-at c-block-stmt-2-key)
		   (looking-at c-block-stmt-1-2-key)))
	      (and (looking-at c-paren-clause-key)
		   (zerop (c-backward-token-2 1 t lim))
		   (if (looking-at c-negation-op-re)
		       (zerop (c-backward-token-2 1 t lim))
		     t)
		   (looking-at c-block-stmt-with-key))))
	 (point))))