Function: cider--treesit-install-font-lock

cider--treesit-install-font-lock is a byte-compiled function defined in cider-mode.el.

Signature

(cider--treesit-install-font-lock FEATURE RULES)

Documentation

Install RULES under FEATURE in the current buffer's treesit settings.

Replace any prior settings for FEATURE. RULES are appended so they run after (and thus override) clojure-ts-mode's own fontification; FEATURE is enabled by adding it to the first, always-active feature level, without shifting the existing levels or mutating the shared literal. When RULES is nil, FEATURE is simply removed.

Source Code

;; Defined in ~/.emacs.d/elpa/cider-20260822.1520/cider-mode.el
(defun cider--treesit-install-font-lock (feature rules)
  "Install RULES under FEATURE in the current buffer's treesit settings.
Replace any prior settings for FEATURE.  RULES are appended so they run
after (and thus override) clojure-ts-mode's own fontification; FEATURE is
enabled by adding it to the first, always-active feature level, without
shifting the existing levels or mutating the shared literal.  When RULES is
nil, FEATURE is simply removed."
  (setq-local treesit-font-lock-settings
              (seq-remove (lambda (s) (eq (nth 2 s) feature))
                          treesit-font-lock-settings))
  (when rules
    (setq-local treesit-font-lock-settings
                (append treesit-font-lock-settings rules))
    (unless (memq feature (apply #'append treesit-font-lock-feature-list))
      (setq-local treesit-font-lock-feature-list
                  (cons (cons feature (car treesit-font-lock-feature-list))
                        (cdr treesit-font-lock-feature-list)))))
  (treesit-font-lock-recompute-features)
  (font-lock-flush))