Function: cider-load-file-handler

cider-load-file-handler is a byte-compiled function defined in cider-eval.el.

Signature

(cider-load-file-handler &optional BUFFER DONE-HANDLER)

Documentation

Make a load file handler for BUFFER.

Optional argument DONE-HANDLER lambda will be run once load is complete.

Source Code

;; Defined in ~/.emacs.d/elpa/cider-20260414.1619/cider-eval.el
(defun cider-load-file-handler (&optional buffer done-handler)
  "Make a load file handler for BUFFER.
Optional argument DONE-HANDLER lambda will be run once load is complete."
  (let ((eval-buffer (current-buffer))
        (res ""))
    (nrepl-make-response-handler (or buffer eval-buffer)
                                 ;; value
                                 (lambda (buffer value)
                                   (cider--display-interactive-eval-result value 'value)
                                   (when cider-eval-register
                                     (setq res (concat res value)))
                                   (when (buffer-live-p buffer)
                                     (with-current-buffer buffer
                                       (cider--make-fringe-overlays-for-region (point-min) (point-max))
                                       (run-hooks 'cider-file-loaded-hook))))
                                 ;; stdout
                                 (lambda (_buffer value)
                                   (cider-emit-interactive-eval-output value))
                                 ;; stderr
                                 (lambda (_buffer err)
                                   (cider-emit-interactive-eval-err-output err)
                                   (cider-handle-compilation-errors err eval-buffer))
                                 ;; done
                                 (lambda (buffer)
                                   (when cider-eval-register
                                     (set-register cider-eval-register res))
                                   (when done-handler
                                     (funcall done-handler buffer))))))