Function: corfu-quick--keys

corfu-quick--keys is a byte-compiled function defined in corfu-quick.el.

Signature

(corfu-quick--keys TWO IDX)

Documentation

Format quick keys prefix.

IDX is the current candidate index. TWO is non-nil if two keys should be displayed.

Source Code

;; Defined in ~/.emacs.d/elpa/corfu-20260821.1158/corfu-quick.el
(defun corfu-quick--keys (two idx) ;; See vertico-quick--keys
  "Format quick keys prefix.
IDX is the current candidate index.
TWO is non-nil if two keys should be displayed."
  (let ((fst (length corfu-quick1))
        (snd (length corfu-quick2)))
    (if (>= idx fst)
        (let ((first (elt corfu-quick2 (mod (/ (- idx fst) fst) snd)))
              (second (elt corfu-quick1 (mod (- idx fst) fst))))
          (cond
           ((eq first two)
            (list
             (propertize (char-to-string second) 'face 'corfu-quick1)
             (cons second (+ corfu--scroll idx))))
           (two
            (list ""))
           (t
            (list
             (concat (propertize (char-to-string first) 'face 'corfu-quick1)
                     (propertize (char-to-string second) 'face 'corfu-quick2))
             (cons first (list first))))))
      (let ((first (elt corfu-quick1 (mod idx fst))))
        (if two
            (list "")
          (list
           (propertize (char-to-string first) 'face 'corfu-quick1)
           (cons first (+ corfu--scroll idx))))))))