Function: customize-package-emacs-version

customize-package-emacs-version is a byte-compiled function defined in cus-edit.el.gz.

Signature

(customize-package-emacs-version SYMBOL PACKAGE-VERSION)

Documentation

Return the Emacs version in which SYMBOL's meaning last changed.

PACKAGE-VERSION has the form (PACKAGE . VERSION). We use customize-package-emacs-version-alist to find the version of Emacs that is associated with version VERSION of PACKAGE.

Source Code

;; Defined in /usr/src/emacs/lisp/cus-edit.el.gz
(defun customize-package-emacs-version (symbol package-version)
  "Return the Emacs version in which SYMBOL's meaning last changed.
PACKAGE-VERSION has the form (PACKAGE . VERSION).  We use
`customize-package-emacs-version-alist' to find the version of
Emacs that is associated with version VERSION of PACKAGE."
  (let (package-versions emacs-version)
    ;; Use message instead of error since we want user to be able to
    ;; see the rest of the symbols even if a package author has
    ;; botched things up.
    (cond ((not (listp package-version))
           (message "Invalid package-version value for %s" symbol))
          ((setq package-versions (assq (car package-version)
                                        customize-package-emacs-version-alist))
           (setq emacs-version
                 (cdr (assoc (cdr package-version) package-versions)))
           (unless emacs-version
             (message "%s version %s not found in %s" symbol
                      (cdr package-version)
                      "customize-package-emacs-version-alist")))
          (t
           (message "Package %s version %s lists no corresponding Emacs version"
                    (car package-version)
                    (cdr package-version))))
    emacs-version))