Function: dcl-option-value-basic

dcl-option-value-basic is a byte-compiled function defined in dcl-mode.el.gz.

Signature

(dcl-option-value-basic OPTION-ASSOC)

Documentation

Guess a value for basic-offset.

Source Code

;; Defined in /usr/src/emacs/lisp/progmodes/dcl-mode.el.gz
;;; *** Set options *********************************************************


;;;-------------------------------------------------------------------------
(defun dcl-option-value-basic (_option-assoc)
  "Guess a value for basic-offset."
  (save-excursion
    (dcl-beginning-of-command)
    (let* (;; current lines indentation
	   (this-indent (save-excursion
			  (dcl-back-to-indentation)
			  (current-column)))
	   ;; previous lines indentation
	   (prev-indent (save-excursion
			  (if (dcl-backward-command)
			      (progn
				(dcl-back-to-indentation)
				(current-column)))))
	   (next-indent (save-excursion
			  (dcl-end-of-command)
			  (if (dcl-forward-command)
			      (progn
				(dcl-beginning-of-command)
				(dcl-back-to-indentation)
				(current-column)))))
	   (diff (if prev-indent
		     (abs (- this-indent prev-indent)))))
      (cond
       ((and diff
	     (/= diff 0))
	diff)
       ((and next-indent
	     (/= (- this-indent next-indent) 0))
	(abs (- this-indent next-indent)))
       (t
	dcl-basic-offset)))))