Function: debbugs-version-sufficient-p

debbugs-version-sufficient-p is a byte-compiled function defined in hib-debbugs.el.

Signature

(debbugs-version-sufficient-p)

Documentation

Return t iff debbugs version is sufficient for use with Hyperbole.

Must be greater than equal to 0.9.7.

Source Code

;; Defined in ~/.emacs.d/elpa/hyperbole-20260414.325/hib-debbugs.el
(defun debbugs-version-sufficient-p ()
  "Return t iff debbugs version is sufficient for use with Hyperbole.
Must be greater than equal to 0.9.7."
  (save-excursion
    (let* ((debbugs-src (or (locate-file "debbugs" load-path '(".el"))
			    (locate-file "debbugs-gnu" load-path '(".el"))))
	   (visiting-debbugs-src (when debbugs-src (get-file-buffer debbugs-src)))
	   debbugs-src-buffer
	   version)
      (when debbugs-src
	(unwind-protect
	    (if (string-match "debbugs-\\([0-9]+.[0-9]+\\(.[0-9]+\\)?\\)" debbugs-src)
		(setq version (match-string 1 debbugs-src))
	      (set-buffer (setq debbugs-src-buffer (find-file-noselect debbugs-src)))
	      (widen)
	      (goto-char (point-min))
	      (when (re-search-forward "^;; Version: \\([.0-9]+\\)" nil t)
		(setq version (match-string 1))))
	  (unless (or visiting-debbugs-src (null debbugs-src-buffer))
	    (kill-buffer debbugs-src-buffer)))
	(when (and version (not (equal version "")))
	  (version-list-<= (version-to-list "0.9.7") (version-to-list version)))))))