Function: doc-view-pdf->png-converter-mupdf

doc-view-pdf->png-converter-mupdf is a byte-compiled function defined in doc-view.el.gz.

Signature

(doc-view-pdf->png-converter-mupdf PDF PNG PAGE CALLBACK)

Source Code

;; Defined in /usr/src/emacs/lisp/doc-view.el.gz
(defun doc-view-pdf->png-converter-mupdf (pdf png page callback)
  (let* ((pdf-passwd (if (doc-view-pdf-password-protected-pdfdraw-p pdf)
                         (read-passwd "Enter password for PDF file: ")))
         (options `(,(concat "-o" png)
                    ,(format "-r%d" (round doc-view-resolution))
                    ,@(if pdf-passwd `("-p" ,pdf-passwd)))))
    (when (eq doc-view-doc-type 'epub)
      (when doc-view-epub-font-size
        (setq options (append options
                              (list (format "-S%s" doc-view-epub-font-size)))))
      (when doc-view-epub-user-stylesheet
        (setq options
              (append options
                      (list (format "-U%s"
                                    (expand-file-name
                                     doc-view-epub-user-stylesheet)))))))
    (doc-view-start-process
     (concat "pdf->" (symbol-name doc-view--image-type))
     doc-view-pdfdraw-program
     `(,@(doc-view-pdfdraw-program-subcommand)
       ,@options
       ,pdf
       ,@(if page `(,(format "%d" page))))
     callback)))