Function: dos-convert-standard-filename

dos-convert-standard-filename is a byte-compiled function defined in dos-fns.el.gz.

Signature

(dos-convert-standard-filename FILENAME)

Documentation

Convert a standard file's name to something suitable for MS-DOS.

This means to guarantee valid names and perhaps to canonicalize certain patterns.

This function is called by convert-standard-filename.

On Windows and DOS, replace invalid characters. On DOS, make sure to obey the 8.3 limitations.

Source Code

;; Defined in /usr/src/emacs/lisp/dos-fns.el.gz
;; See convert-standard-filename in files.el.
(defun dos-convert-standard-filename (filename)
  "Convert a standard file's name to something suitable for MS-DOS.
This means to guarantee valid names and perhaps to canonicalize
certain patterns.

This function is called by `convert-standard-filename'.

On Windows and DOS, replace invalid characters.  On DOS, make
sure to obey the 8.3 limitations."
  (if (or (not (stringp filename))
	  ;; This catches the case where FILENAME is "x:" or "x:/" or
	  ;; "/", thus preventing infinite recursion.
	  (string-match "\\`\\([a-zA-Z]:\\)?[/\\]?\\'" filename))
      filename
    (let ((flen (length filename)))
      ;; If FILENAME has a trailing slash, remove it and recurse.
      (if (memq (aref filename (1- flen)) '(?/ ?\\))
	  (concat (dos-convert-standard-filename
		   (substring filename 0 (1- flen)))
		  "/")
	(let* (;; ange-ftp gets in the way for names like "/foo:bar".
	       ;; We need to inhibit all magic file names, because
	       ;; remote file names should never be passed through
	       ;; this function, as they are not meant for the local
	       ;; filesystem!
	       (file-name-handler-alist nil)
	       (dir
		;; If FILENAME is "x:foo", file-name-directory returns
		;; "x:/bar/baz", substituting the current working
		;; directory on drive x:.  We want to be left with "x:"
		;; instead.
		(if (and (< 1 flen)
			 (eq (aref filename 1) ?:)
			 (null (string-match "[/\\]" filename)))
		    (substring filename 0 2)
		  (file-name-directory filename)))
	       (dlen-m-1 (1- (length dir)))
	       (string (copy-sequence (file-name-nondirectory filename)))
	       (lastchar (aref string (1- (length string))))
	       i firstdot)
	  (cond
	   ((msdos-long-file-names)
	    ;; Replace characters that are invalid even on Windows.
	    (while (setq i (string-match "[?*:<>|\"\000-\037]" string))
	      (aset string i ?!)))
	   ((not (member string '("" "." "..")))
	    ;; Change a leading period to a leading underscore.
	    (if (= (aref string 0) ?.)
		(aset string 0 ?_))
	    ;; If the name is longer than 8 chars, and doesn't have a
	    ;; period, and we have a dash or underscore that isn't too
	    ;; close to the beginning, change that to a period.  This
	    ;; is so we could salvage more characters of the original
	    ;; name by pushing them into the extension.
	    (if (and (not (string-search "." string))
		     (> (length string) 8)
		     ;; We don't gain anything if we put the period closer
		     ;; than 5 chars from the beginning (5 + 3 = 8).
		     (setq i (string-match "[-_]" string 5)))
		(aset string i ?\.))
	    ;; Get rid of invalid characters.
	    (while (setq i (string-match
			    "[^-a-zA-Z0-9_.%~^$!#&{}@`'()\200-\376]"
			    string))
	      (aset string i ?_))
	    ;; If we don't have a period in the first 8 chars, insert one.
	    ;; This enables having 3 more characters from the original
	    ;; name in the extension.
	    (if (> (or (string-search "." string) (length string))
		   8)
		(setq string
		      (concat (substring string 0 8)
			      "."
			      (substring string 8))))
	    (setq firstdot (or (string-search "." string)
			       (1- (length string))))
	    ;; Truncate to 3 chars after the first period.
	    (if (> (length string) (+ firstdot 4))
		(setq string (substring string 0 (+ firstdot 4))))
	    ;; Change all periods except the first one into underscores.
	    ;; (DOS doesn't allow more than one period.)
	    (while (string-search "." string (1+ firstdot))
	      (setq i (string-search "." string (1+ firstdot)))
	      (aset string i ?_))
	    ;; If the last character of the original filename was `~' or `#',
	    ;; make sure the munged name ends with it also.  This is so that
	    ;; backup and auto-save files retain their telltale form.
	    (if (memq lastchar '(?~ ?#))
		(aset string (1- (length string)) lastchar))))
	  (concat (if (and (stringp dir)
			   (memq (aref dir dlen-m-1) '(?/ ?\\)))
		      (concat (dos-convert-standard-filename
			       (substring dir 0 dlen-m-1))
			      "/")
		    (dos-convert-standard-filename dir))
		  string))))))