Function: emacs-build-description

emacs-build-description is an autoloaded, interactive and byte-compiled function defined in emacsbug.el.gz.

Signature

(emacs-build-description)

Documentation

Insert a description of the current Emacs build in the current buffer.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/mail/emacsbug.el.gz
;;;###autoload
(defun emacs-build-description ()
  "Insert a description of the current Emacs build in the current buffer."
  (interactive)
  (let ((start (point)))
    (insert "\nIn " (emacs-version))
    (if emacs-build-system
        (insert " built on " emacs-build-system))
    (insert "\n")
    (fill-region-as-paragraph start (point)))

  (if (stringp emacs-repository-version)
      (insert "Repository revision: " emacs-repository-version "\n"))
  (if (stringp emacs-repository-branch)
      (insert "Repository branch: " emacs-repository-branch "\n"))
  (if (fboundp 'x-server-vendor)
      (condition-case nil
          ;; This is used not only for X11 but also W32 and others.
	  (insert "Windowing system distributor '" (x-server-vendor)
                  "', version "
		  (mapconcat #'number-to-string (x-server-version) ".") "\n")
	(error t)))
  (let ((os (ignore-errors (report-emacs-bug--os-description))))
    (if (stringp os)
        (insert "System Description: " os "\n\n")))
  (when (and system-configuration-options
	     (not (equal system-configuration-options "")))
    (insert "Configured using:\n 'configure "
	    system-configuration-options "'\n\n")
    (fill-region (line-beginning-position -1) (point))))