Function: emacs-news-next-untagged-entry

emacs-news-next-untagged-entry is an interactive and byte-compiled function defined in emacs-news-mode.el.gz.

Signature

(emacs-news-next-untagged-entry &optional REVERSE)

Documentation

Go to the next untagged NEWS entry.

If REVERSE (interactively, the prefix), go to the previous untagged NEWS entry.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/textmodes/emacs-news-mode.el.gz
(defun emacs-news-next-untagged-entry (&optional reverse)
  "Go to the next untagged NEWS entry.
If REVERSE (interactively, the prefix), go to the previous
untagged NEWS entry."
  (interactive "P" emacs-news-mode)
  (let ((start (point))
        (found nil))
    ;; Don't consider the current line, because that would stop
    ;; progress if calling this command repeatedly.
    (unless reverse
      (forward-line 1))
    (while (and (not found)
                (funcall (if reverse #'re-search-backward
                           #'re-search-forward)
                         "^\\(\\*+\\) " nil t))
      (when (and (not (save-excursion
                        (forward-line -1)
                        (looking-at "---$\\|\\+\\+\\+$")))
                 ;; We have an entry without a tag before it, but
                 ;; check whether it's a heading (which we can
                 ;; determine if the next entry has more asterisks).
                 (not (emacs-news--heading-p)))
        ;; It wasn't a sub-heading, so we've found one.
        (setq found t)))
    (if found
        (progn
          (push-mark start)
          (message "Untagged entry")
          (beginning-of-line)
          t)
      (message "No further untagged entries")
      (goto-char start)
      nil)))