Function: erc-server-join-channel

erc-server-join-channel is a byte-compiled function defined in erc.el.gz.

Signature

(erc-server-join-channel SERVER CHANNEL &optional SECRET)

Documentation

Join CHANNEL, optionally with SECRET.

Without SECRET, consult auth-source, possibly passing SERVER as the
:host query parameter.

Source Code

;; Defined in /usr/src/emacs/lisp/erc/erc.el.gz
(defun erc-server-join-channel (server channel &optional secret)
  "Join CHANNEL, optionally with SECRET.
Without SECRET, consult auth-source, possibly passing SERVER as the
`:host' query parameter."
  (unless (or secret (not erc-auth-source-join-function))
    (unless server
      (when (and erc-server-announced-name
                 (erc--valid-local-channel-p channel))
        (setq server erc-server-announced-name)))
    (setq secret (apply erc-auth-source-join-function
                        `(,@(and server (list :host server)) :user ,channel))))
  (erc-log (format "cmd: JOIN: %s" channel))
  (erc-server-send (concat "JOIN " channel
                           (and secret (concat " " (erc--unfun secret))))))