Function: eww-desktop-misc-data

eww-desktop-misc-data is a byte-compiled function defined in eww.el.gz.

Signature

(eww-desktop-misc-data DIRECTORY)

Documentation

Return a property list with data used to restore eww buffers.

This list will contain, as :history, the list, whose first element is the value of eww-data, and the tail is eww-history.

If eww-desktop-remove-duplicates is non-nil, duplicate entries (if any) will be removed from the list.

Only the properties listed in eww-desktop-data-save are included. Generally, the list should not include the (usually overly large)
:dom, :source and :text properties.

Source Code

;; Defined in /usr/src/emacs/lisp/net/eww.el.gz
(defun eww-desktop-misc-data (_directory)
  "Return a property list with data used to restore eww buffers.
This list will contain, as :history, the list, whose first element is
the value of `eww-data', and the tail is `eww-history'.

If `eww-desktop-remove-duplicates' is non-nil, duplicate
entries (if any) will be removed from the list.

Only the properties listed in `eww-desktop-data-save' are included.
Generally, the list should not include the (usually overly large)
:dom, :source and :text properties."
  (let ((history (mapcar #'eww-desktop-data-1
                         (cons eww-data eww-history)))
        (posn eww-history-position) rval)
    (list :history
          (if eww-desktop-remove-duplicates
              (prog1
                  (setq
                   rval (cl-remove-duplicates
                         history :test #'eww-desktop-history-duplicate))
                (setq posn
                      (cl-position
                       (elt history eww-history-position)
                       rval :test #'eq)))
            history)
          :history-position posn)))