Function: eww-display-html

eww-display-html is a byte-compiled function defined in eww.el.gz.

Signature

(eww-display-html CHARSET URL &optional DOCUMENT POINT BUFFER)

Source Code

;; Defined in /usr/src/emacs/lisp/net/eww.el.gz
(defun eww-display-html (charset url &optional document point buffer)
  (let ((source (buffer-substring (point) (point-max))))
    (with-current-buffer buffer
      (plist-put eww-data :source source)))
  (unless document
    (let ((dom (eww--parse-html-region (point) (point-max) charset)))
      (when (eww-default-readable-p url)
        ;; HACK: Work around bug#77299.  By displaying the full
        ;; document first, we can ensure that the `:title' property in
        ;; `eww-data' gets set properly.  This is inefficient, since
        ;; it requires rendering the document twice.
        (let ((shr-inhibit-images t))
          (eww-display-document (eww-document-base url dom) point buffer))
        (eww-score-readability dom)
        (setq dom (eww-highest-readability dom))
        (with-current-buffer buffer
          (plist-put eww-data :readable t)))
      (setq document (eww-document-base url dom))))
  (eww-display-document document point buffer))