Function: filesets-open

filesets-open is an interactive and byte-compiled function defined in filesets.el.gz.

Signature

(filesets-open &optional MODE NAME LOOKUP-NAME)

Documentation

Open the fileset called NAME.

Use LOOKUP-NAME for searching additional data if provided.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/filesets.el.gz
(defun filesets-open (&optional mode name lookup-name)
  "Open the fileset called NAME.
Use LOOKUP-NAME for searching additional data if provided."
  (interactive)
  (let* ((name (or name
		   (completing-read "Open fileset: " filesets-data nil t)))
	 (fileset (filesets-get-fileset-from-name name mode))
	 (lookup-fs (if lookup-name
			(filesets-get-fileset-from-name lookup-name)
		      fileset))
	 (mode (or mode (filesets-entry-mode lookup-fs))))
    (if fileset
	(let* ((files         (filesets-get-filelist fileset mode 'on-open-all))
	       (n             (length files))
	       (open-function (filesets-entry-get-open-fn nil lookup-fs)))
	  (if (or (<= n filesets-query-user-limit)
		  (y-or-n-p (format "Filesets: Open all %d files in %s? "
				    n name)))
	      (dolist (this files nil)
		(filesets-file-open open-function this))
	    (message "Filesets: canceled")))
      (error "Filesets: Unknown fileset: %s" name))))