Function: forge-dispatch

forge-dispatch is an autoloaded, interactive and byte-compiled function defined in forge-commands.el.

Signature

(forge-dispatch)

Documentation

Dispatch a forge command.

Key Bindings

Source Code

;; Defined in ~/.emacs.d/elpa/forge-20260408.1922/forge-commands.el
;;; Dispatch

;;;###autoload(autoload 'forge-dispatch "forge-commands" nil t)
(transient-define-prefix forge-dispatch ()
  "Dispatch a forge command."
  :transient-non-suffix #'transient--do-call
  :refresh-suffixes t
  :environment #'forge--menu-environment
  :column-widths forge--topic-menus-column-widths
  [forge--topic-menus-group
   ["Fetch"
    ("f f" "all topics"     forge-pull)
    ("f t" "one topic"      forge-pull-topic)
    ("f n" "notifications"  forge-pull-notifications)]
   ["Create"
    :if (##forge-get-repository :tracked?)
    ("c d" "discussion"     forge-create-discussion)
    ("c i" "issue"          forge-create-issue)
    ("c p" "pull-request"   forge-create-pullreq)
    ("c u" "pr from issue"  forge-create-pullreq-from-issue)
    ("c f" "fork or remote" forge-fork)]
   [:description (lambda ()
                   (cond
                     ((forge-get-repository :tracked?) "Actions")
                     ((or (magit-gitdir) (forge-repository-at-point))
                      "Forge does not yet track this repository")
                     ("Not inside a Git repository")))
    ("/ a" forge-add-repository
     :description (lambda () (let ((repo (forge-get-repository :stub?)))
                          (if (or (not repo)
                                  (eq (oref repo condition) :tracked))
                            "track some repo"
                          "track this repository"))))
    ("c f" "fork this repository" forge-fork
     :if-not (##forge-get-repository :tracked?))
    ("/ M" "merge with api" forge-merge
     :if (##forge-get-repository :tracked?)
     :level 7)]]
  [forge--lists-group
   ["Visit"
    :inapt-if-not (##forge-get-repository :tracked?)
    ("v t" "topic"          forge-visit-topic)
    ("v u" "topic from url" forge-visit-topic-from-url :level 0)
    ("v d" "discussion"     forge-visit-discussion)
    ("v i" "issue"          forge-visit-issue)
    ("v p" "pull-request"   forge-visit-pullreq)]
   ["Browse"
    ("b t" "topic"          forge-browse-topic
     :inapt-if-not (##forge-get-repository :tracked?))
    ("b i" "issue"          forge-browse-issue
     :inapt-if-not (##forge-get-repository :tracked?))
    ("b p" "pull-request"   forge-browse-pullreq
     :inapt-if-not (##forge-get-repository :tracked?))
    ("b r" "remote"         forge-browse-remote)
    ("b I" "issues"         forge-browse-issues)
    ("b P" "pull-requests"  forge-browse-pullreqs)
    ""]
   ["Display"
    ("-S" forge-toggle-display-in-status-buffer
     :inapt-if-not forge--buffer-with-topics-sections-p)
    ("-H" forge-toggle-topic-legend)]]
  [forge--topic-legend-group])