Function: forge-insert-notification

forge-insert-notification is a byte-compiled function defined in forge-notify.el.

Signature

(forge-insert-notification NOTIF)

Source Code

;; Defined in ~/.emacs.d/elpa/forge-20260408.1922/forge-notify.el
(defun forge-insert-notification (notif)
  (with-slots (type title url) notif
    (pcase type
      ((or 'discussion 'issue 'pullreq)
       (forge--insert-topic (forge-get-topic notif)))
      ('commit
       (magit-insert-section (ncommit nil) ; !commit
         (string-match "[^/]*\\'" url)
         (insert
          (format "%s %s\n"
                  (propertize (substring (match-string 0 url)
                                         0 (magit-abbrev-length))
                              'font-lock-face 'magit-hash)
                  (magit-log--wash-summary
                   (propertize title 'font-lock-face
                               (if-let* ((topic (oref notif topic))
                                         (_(eq (oref topic status) 'unread)))
                                   'forge-topic-unread
                                 'forge-topic-open)))))))
      (_
       ;; The documentation does not mention what "types"
       ;; exist.  Make it obvious that this is something
       ;; we do not know how to handle properly yet.
       (magit-insert-section (notification notif)
         (insert (propertize (format "(%s) %s\n" type title)
                             'font-lock-face 'error)))))))