Function: fortran-find-comment-start-skip

fortran-find-comment-start-skip is a byte-compiled function defined in fortran.el.gz.

Signature

(fortran-find-comment-start-skip &optional ALL)

Documentation

Move to past comment-start-skip found on current line.

Return non-nil if comment-start-skip found, nil if not. If ALL is nil, only match comments that start in column > 0.

Source Code

;; Defined in /usr/src/emacs/lisp/progmodes/fortran.el.gz
(defun fortran-find-comment-start-skip (&optional all)
  "Move to past `comment-start-skip' found on current line.
Return non-nil if `comment-start-skip' found, nil if not.
If ALL is nil, only match comments that start in column > 0."
  ;; Hopefully at some point we can just use the line below!  -stef
  ;; (comment-search-forward (line-end-position) t))
  (when (or all comment-start-skip)
    (let ((pos (point))
          (css (if comment-start-skip
                   (concat fortran-comment-line-start-skip
                           "\\|" comment-start-skip)
                 fortran-comment-line-start-skip)))
      (when (re-search-forward css (line-end-position) t)
        (if (and (or all (> (match-beginning 0) (line-beginning-position)))
                 (or (save-match-data
                       (not (fortran-is-in-string-p (match-beginning 0))))
                     ;; Recurse for rest of line.
                     (fortran-find-comment-start-skip all)))
            (point)
          (goto-char pos)
          nil)))))