Function: gdb-create-define-alist

gdb-create-define-alist is a byte-compiled function defined in gdb-mi.el.gz.

Signature

(gdb-create-define-alist)

Documentation

Create an alist of #define directives for GUD tooltips.

Source Code

;; Defined in /usr/src/emacs/lisp/progmodes/gdb-mi.el.gz
(defun gdb-create-define-alist ()
  "Create an alist of #define directives for GUD tooltips."
  (let* ((file (buffer-file-name))
	 (output
	  (with-output-to-string
	    (with-current-buffer standard-output
              (and file
		   (file-exists-p file)
                   ;; call-process doesn't work with remote file names.
		   (not (file-remote-p default-directory))
                   (call-process shell-file-name file
				 (list t nil) nil "-c"
				 (concat gdb-cpp-define-alist-program " "
					 gdb-cpp-define-alist-flags))))))
         (define-list (split-string output "\n" t))
         (name))
    (setq gdb-define-alist nil)
    (dolist (define define-list)
      (setq name (nth 1 (split-string define "[( ]")))
      (push (cons name define) gdb-define-alist))))