Function: gnus-forward-line-ignore-invisible

gnus-forward-line-ignore-invisible is a byte-compiled function defined in gnus-sum.el.gz.

Signature

(gnus-forward-line-ignore-invisible N)

Documentation

Move N lines forward (backward if N is negative).

Like forward-line, but skip over (and don't count) invisible lines.

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/gnus-sum.el.gz
(defun gnus-forward-line-ignore-invisible (n)
  "Move N lines forward (backward if N is negative).
Like `forward-line', but skip over (and don't count) invisible lines."
  (let (done)
    (while (and (> n 0) (not done))
      ;; If the following character is currently invisible,
      ;; skip all characters with that same `invisible' property value.
      (while (invisible-p (point))
	(goto-char (next-char-property-change (point))))
      (forward-line 1)
      (if (eobp)
	  (setq done t)
	(setq n (1- n))))
    (while (and (< n 0) (not done))
      (forward-line -1)
      (if (bobp) (setq done t)
	(setq n (1+ n))
	(while (and (not (bobp)) (invisible-p (1- (point))))
	  (goto-char (previous-char-property-change (point))))))))