Function: gnus-group-send-queue

gnus-group-send-queue is an autoloaded, interactive and byte-compiled function defined in gnus-draft.el.gz.

Signature

(gnus-group-send-queue)

Documentation

Send all sendable articles from the queue group.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/gnus-draft.el.gz
(defun gnus-group-send-queue ()
  "Send all sendable articles from the queue group."
  (interactive)
  (when (or gnus-plugged
	    (not gnus-agent-prompt-send-queue)
	    (gnus-y-or-n-p "Gnus is unplugged; really send queue? "))
    (gnus-activate-group "nndraft:queue")
    (save-excursion
      (let* ((articles (nndraft-articles))
	     (unsendable (range-uncompress
			  (cdr (assq 'unsend
				     (gnus-info-marks
				      (gnus-get-info "nndraft:queue"))))))
	     (gnus-posting-styles nil)
	     message-send-mail-partially-limit
	     (total (length articles))
	     article)
	(while (setq article (pop articles))
	  (unless (memq article unsendable)
	    (let ((message-sending-message
		   (format "Sending message %d of %d..."
			   (- total (length articles)) total)))
	      (gnus-draft-send article))))))
    (gnus-group-refresh-group "nndraft:queue")))