Function: gnus-mime-view-part-externally

gnus-mime-view-part-externally is an interactive and byte-compiled function defined in gnus-art.el.gz.

Signature

(gnus-mime-view-part-externally &optional HANDLE EVENT)

Documentation

View the MIME part under point with an external viewer.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/gnus-art.el.gz
(defun gnus-mime-view-part-externally (&optional handle event)
  "View the MIME part under point with an external viewer."
  (interactive (list nil last-nonmenu-event) gnus-article-mode)
  (save-excursion
    (mouse-set-point event)
    (gnus-article-check-buffer)
    (let* ((handle (or handle (get-text-property (point) 'gnus-data)))
	   (mm-inlined-types nil)
	   (mail-parse-charset gnus-newsgroup-charset)
	   (mail-parse-ignored-charsets
            (with-current-buffer gnus-summary-buffer
              gnus-newsgroup-ignored-charsets))
           (type (mm-handle-media-type handle))
           (method (mailcap-mime-info type))
           (mm-enable-external t))
      (if (not (stringp method))
	  (gnus-mime-view-part-as-type
	   nil (lambda (type) (stringp (mailcap-mime-info type))))
	(when handle
	  (mm-display-part handle nil t))))))