Function: hmouse-modeline-default-help-echo

hmouse-modeline-default-help-echo is a byte-compiled function defined in hui-window.el.

Signature

(hmouse-modeline-default-help-echo WINDOW)

Documentation

Return default help echo text for WINDOW's mode line.

Source Code

;; Defined in ~/.emacs.d/elpa/hyperbole-20260414.325/hui-window.el
;; Derived from bindings.el
(defun hmouse-modeline-default-help-echo (window)
  "Return default help echo text for WINDOW's mode line."
  (let* ((frame (window-frame window))
         (line-1a
          ;; Show text to select window only if the window is not
          ;; selected.
          (not (eq window (frame-selected-window frame))))
         (line-1b
          ;; Show text to drag mode line if either the window is not
          ;; at the bottom of its frame or the minibuffer window of
          ;; this frame can be resized.  This matches a corresponding
          ;; check in `mouse-drag-mode-line'.
          (or (not (window-at-side-p window 'bottom))
              (let ((mini-window (minibuffer-window frame)))
                (and (eq frame (window-frame mini-window))
                     (or (minibuffer-window-active-p mini-window)
                         (not resize-mini-windows))))))
         (line-2a
	  (and (boundp 'hyperbole-mode) hyperbole-mode))
         (line-2b
          ;; Show text make window occupy the whole frame
          ;; only if it doesn't already do that.
          (not (eq window (frame-root-window frame))))
         (line-3
          ;; Show text to delete window only if that's possible.
          (not (eq window (frame-root-window frame)))))
    (when (or line-1a line-1b line-2a line-2b line-3)
      (concat
       (when (or line-1a line-1b)
         (concat
          "mouse-1: "
	  (when line-2a "           ")
          (when line-1a "Select window")
          (when line-1b
            (if line-1a " (drag to resize)" "Drag to resize"))
          (when (or line-2a line-2b line-3) "\n")))
       (cond (line-2a
	      (concat
               "mouse-2:            Show/hide buffer menu\n"
               "mouse-2 right edge: Show/hide Info manuals buffer\n"))
	     (line-2b
              (concat
               "mouse-2: Make window occupy whole frame"
               (when line-3 "\n"))))
       (cond (line-2a
	      (concat
               "mouse-3:            Screen Control and Jump Menus\n"
               "mouse-3 right edge: Show/hide Action/Assist Key actions"))
	     (line-3
              "mouse-3: Remove window from frame"))))))