Function: hyrolo-tags-view

hyrolo-tags-view is an autoloaded, interactive and byte-compiled function defined in hyrolo.el.

Signature

(hyrolo-tags-view &optional TODO-ONLY MATCH VIEW-BUFFER-NAME)

Documentation

Prompt for colon-separated Org tags and display matching HyRolo sections.

With optional prefix arg TODO-ONLY, limit matches to HyRolo Org todo items only. With optional MATCH, an Org tags match selector string, e.g. ":tag1:tag2:tag3:", match to sections that contain or inherit all of these tags, regardless of tag order. With optional VIEW-BUFFER-NAME, use that rather than the default,
"*HyRolo Tags*".

Key Bindings

Source Code

;; Defined in ~/.emacs.d/elpa/hyperbole-20260414.325/hyrolo.el
;;;###autoload
(defun hyrolo-tags-view (&optional todo-only match view-buffer-name)
  "Prompt for colon-separated Org tags and display matching HyRolo sections.
With optional prefix arg TODO-ONLY, limit matches to HyRolo Org
todo items only.  With optional MATCH, an Org tags match selector
string, e.g. \":tag1:tag2:tag3:\", match to sections that contain
or inherit all of these tags, regardless of tag order.  With
optional VIEW-BUFFER-NAME, use that rather than the default,
\"*HyRolo Tags*\"."
  (interactive "P")
  (require 'org-agenda)
  (let* ((org-agenda-files (seq-filter (lambda (f)
					 (string-suffix-p ".org" f t))
				       (hyrolo-get-file-list)))
	 (org-agenda-buffer-name (or view-buffer-name "*HyRolo Tags*"))
	 ;; `org-tags-view' is mis-written to require setting this next
	 ;; tmp-name or it will not properly name the displayed buffer.
	 (org-agenda-buffer-tmp-name org-agenda-buffer-name))
    ;; This prompts for the tags to match and uses `org-agenda-files'.
    (org-tags-view todo-only match)
    (when (equal (buffer-name) org-agenda-buffer-name)
      ;; Set up {C-u r} redo cmd
      (let (buffer-read-only)
	(put-text-property (point-min) (point-max) 'org-redo-cmd
			   `(hyrolo-tags-view
			       ,todo-only
			       nil
			       ,org-agenda-buffer-name)))
      (forward-line 2))))